National emissions (non-ETS)/EU

PREFIX clrtap_nec_unfccc: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/schema/>
PREFIX geo: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/country/>
PREFIX sector: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/unfccc_crf_sector/>
PREFIX rdf-schema: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX CITL_v17: <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/CITL_v17.tsv#>
PREFIX ets_2013_vs_2012: <http://semantic.eea.europa.eu/project/ghg_projections/ets_2013_vs_2012.tsv#>

SELECT 
xsd:integer(?year) as ?date
#15959 value taken from unfccc_crf_1_a_3_a for year 2012
bif:either(xsd:integer(?year) = 2013,  round(( sum(?total_sar_gwps) - sum(?CITL_v17)/1000 - 15959 )/10)/100.0, round(( sum(?unfccc_crf_all_sectors) - sum(?CITL_v17)/1000 - sum(?unfccc_crf_1_a_3_a) )/10)/100.0 ) as ?difference
sum(?unfccc_crf_all_sectors/1000) as ?unfccc_crf
sum(?CITL_v17/1000000) as ?CITL
sum(?unfccc_crf_1_a_3_a/1000) as ?unfccc_crf_1_a_3_a
sum(?total_sar_gwps/1000) as ?total_sar_gwps

WHERE {
  { 
  GRAPH <http://r.eionet.europa.eu/rdfdumps/clrtap_nec_unfccc/unfccc_crf.rdf.gz> 
    {
      _:unfccc_crf clrtap_nec_unfccc:country_code ?geo .
      FILTER (?geo = geo:EU28)
      _:unfccc_crf clrtap_nec_unfccc:year ?year . FILTER (xsd:integer(?year) >= 2005)
      {
        _:unfccc_crf clrtap_nec_unfccc:unit ?unit . FILTER (?unit = 'Gg CO2 equivalent')
        _:unfccc_crf clrtap_nec_unfccc:pollutant_name ?pollutant_name . 
        FILTER (?pollutant_name = 'All greenhouse gases - (CO2 equivalent)')
        _:unfccc_crf clrtap_nec_unfccc:sector_code ?sector_code . 
        FILTER (?sector_code in (sector:1, sector:2, sector:3, sector:4, sector:6, sector:7))
        _:unfccc_crf clrtap_nec_unfccc:emissions ?unfccc_crf_all_sectors .
      } UNION {
        _:unfccc_crf clrtap_nec_unfccc:unit ?unit . FILTER (?unit = 'Gg')
        _:unfccc_crf clrtap_nec_unfccc:pollutant_name ?pollutant_name . 
        FILTER (?pollutant_name = 'CO2')
        _:unfccc_crf clrtap_nec_unfccc:sector_code ?sector_code . 
        FILTER (?sector_code in (sector:1.A.3.A))
        _:unfccc_crf clrtap_nec_unfccc:emissions ?unfccc_crf_1_a_3_a .
      }
    }
  } UNION {  
  GRAPH <http://semantic.eea.europa.eu/project/ghg_projections/ets_2013_vs_2012.tsv> 
    {
      _:ets_2013_vs_2012 ets_2013_vs_2012:ugeo geo:EU28 .
      _:ets_2013_vs_2012 ets_2013_vs_2012:year ?year . FILTER (?year = 2013)
      _:ets_2013_vs_2012 ets_2013_vs_2012:Total_SAR_GWPs ?total_sar_gwps .
    } 
  } UNION {  
  GRAPH <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/CITL_v17.tsv> 
    {
      _:CITL_v17 CITL_v17:country_code ?geo .
      _:CITL_v17 CITL_v17:main_activity_sector_name ?main_activity_sector_name . 
      FILTER (?main_activity_sector_name = '20-99 All installations')
      _:CITL_v17 CITL_v17:ETS_information ?ETS_information . 
      FILTER (?ETS_information in ('2. Verified emissions', '1.2 Correction to freely allocated allowances (not reflected in EUTL)'))
      _:CITL_v17 CITL_v17:year ?year . #FILTER (?year = 2013)
      _:CITL_v17 CITL_v17:value ?CITL_v17 .
      _:CITL_v17 CITL_v17:unit ?unit .
      FILTER (?geo in (geo:AT,geo:BE,geo:BG,geo:CY,geo:CZ,geo:DE,geo:DK,geo:EE,geo:ES,geo:FI,geo:FR,geo:GB,geo:GR,geo:HU,geo:IE,
                       geo:IT,geo:LT,geo:LU,geo:LV,geo:MT,geo:NL,geo:PL,geo:PT,geo:RO,geo:SE,geo:SI,geo:SK,geo:HR))
    } 
 }
}
GROUP BY xsd:integer(?year)
HAVING xsd:integer(?year) != ''
ORDER BY ?year