Final energy consumption of electricity by sector

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>
PREFIX indic_nrg: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_nrg/>
PREFIX common_countries: <http://dd.eionet.europa.eu/vocabulary/common/countries/>

SELECT
?date
bif:either(?geo = geo:DE, 'Germany', ?ugeo) as ?ugeo
?sector
bif:either(?sector = 'Fishing, agriculture, forestry and non specified', ?other, ?obsValue) as ?obsValue
bif:either(?sector = 'Fishing, agriculture, forestry and non specified', ?shareOther, ?obsValueShare) as ?obsValueShare
{{
  SELECT DISTINCT
    year(?date) as ?date
    ?geo
    ?ugeo
    ?sector
    round(sum(?obsValue)/100)/10.0 as ?obsValue
    round((sum(?B_102000)-sum(?B_102010)-sum(?B_102035))/100)/10.0 as ?other
    round((sum(?obsValue)/sum(?total))*1000)/10.0 as ?obsValueShare
    (round((sum(?B_102000)-sum(?B_102010)-sum(?B_102035))/(((sum(?total)/3)))*1000))/10.0 as ?shareOther

  WHERE {
  {  
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_105a.rdf.gz> 
    {
    _:nrg_105a_total sdmx-dimension:refArea ?geo .
    _:nrg_105a_total sdmx-attribute:unitMeasure unit:GWH .
    _:nrg_105a_total sdmx-dimension:timePeriod ?date .
    _:nrg_105a_total property:product product:6000 .
      { 
        _:nrg_105a_total property:indic_nrg indic_nrg:B_101700 .      
        _:nrg_105a_total sdmx-measure:obsValue ?total .
      }

    _:nrg_105a sdmx-dimension:refArea ?geo .
    _:nrg_105a sdmx-attribute:unitMeasure unit:GWH .
    _:nrg_105a sdmx-dimension:timePeriod ?date .
    _:nrg_105a property:product product:6000 .
      {
        { SELECT 'Industry' as ?sector {} }
        _:nrg_105a property:indic_nrg indic_nrg:B_101800 .      
        _:nrg_105a sdmx-measure:obsValue ?obsValue .
      } UNION {
        { SELECT 'Transport' as ?sector {} }
        _:nrg_105a property:indic_nrg indic_nrg:B_101900 .      
        _:nrg_105a sdmx-measure:obsValue ?obsValue .
      } UNION {
        { SELECT 'Households' as ?sector {} }
        _:nrg_105a property:indic_nrg indic_nrg:B_102010 .      
        _:nrg_105a sdmx-measure:obsValue ?obsValue .
      } UNION {
        { SELECT 'Services' as ?sector {} }
        _:nrg_105a property:indic_nrg indic_nrg:B_102035 .      
        _:nrg_105a sdmx-measure:obsValue ?obsValue .
      }UNION { 
        { SELECT 'Fishing, agriculture, forestry and non specified' as ?sector {} }
        _:nrg_105a property:indic_nrg indic_nrg:B_102000 .      
        _:nrg_105a sdmx-measure:obsValue ?B_102000 .
      } UNION {
        { SELECT 'Fishing, agriculture, forestry and non specified' as ?sector {} }
        _:nrg_105a property:indic_nrg indic_nrg:B_102010 .      
        _:nrg_105a sdmx-measure:obsValue ?B_102010 .
      } UNION {
        { SELECT 'Fishing, agriculture, forestry and non specified' as ?sector {} }
        _:nrg_105a property:indic_nrg indic_nrg:B_102035 .      
        _:nrg_105a sdmx-measure:obsValue ?B_102035 .
      }
    }
    ?geo rdfs:label ?ugeo .
    FILTER (?geo in (geo:AT, geo:BE, geo:BG, geo:CY, geo:CZ, geo:DE, geo:DK,
                     geo:EE, geo:EL, geo:ES, geo:FI, geo:FR, geo:HR, geo:HU,
                     geo:IE, geo:IT, geo:LT, geo:LU, geo:LV, geo:MT, geo:NL,
                     geo:PL, geo:PT, geo:RO, geo:SE, geo:SI, geo:SK, geo:UK
                     , geo:EU28))
   }
  }
  HAVING sum(?total) > 0
}}
ORDER BY ?date ?ugeo