Final energy consumption by transport modes

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX infotype: <http://rdfdata.eionet.europa.eu/eurostat/dic/infotype#>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX indic_nrg: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_nrg/>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>


SELECT
year(?date) as ?year 
round(sum(?B_100800)/100000)/10.0  as ?International_Marine_Bunkers 
round(sum(?B_101910)/100000)/10.0 as ?Rail_Transport 
round((sum(?B_101920) + sum(?B_101920_el))/100000)/10.0 as ?Road_Transport 
##round(sum(?B_101931)/100000)/10.0 as ?International_Aviation 
##round(sum(?B_101932)/100000)/10.0 as ?Domestic_Aviation 
round(( sum(?B_101931)+sum(?B_101932) )/100000)/10.0 as ?Domestic_International_Aviation 
round(sum(?B_101940)/100000)/10.0 as ?Domestic_Navigation
round(sum(?total)/100000)/10.0 as ?Total
round((sum(?road)+sum(?rail)+sum(?aviation)+sum(?ship))/100000)/10.0 as ?oil_derived_fuels
round((sum(?road)+sum(?rail)+sum(?aviation)+sum(?ship))/100000)/10.0*0.3 AS ?annotation_line_computed 

#use of the computed value for 2008 as constant for all the years 
xsd:double(5.2) as ?annotation_line

  WHERE {{{
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_100a.rdf.gz> { 
    {
        _:nrg_100a sdmx-attribute:unitMeasure unit:TJ .
        _:nrg_100a property:product product:0000 .
        _:nrg_100a sdmx-dimension:refArea ?geo . 
        _:nrg_100a sdmx-dimension:timePeriod ?date .
        { 
          _:nrg_100a property:indic_nrg indic_nrg:B_100800 .
	  _:nrg_100a sdmx-measure:obsValue ?B_100800 .
	} UNION { 
           _:nrg_100a property:indic_nrg indic_nrg:B_101910 .
	  _:nrg_100a sdmx-measure:obsValue ?B_101910 .
	} UNION { 
          _:nrg_100a property:indic_nrg indic_nrg:B_101920 .
	  _:nrg_100a sdmx-measure:obsValue ?B_101920 .
	} UNION { 
          _:nrg_100a property:indic_nrg indic_nrg:B_101931 .
	  _:nrg_100a sdmx-measure:obsValue ?B_101931 .
	} UNION { 
          _:nrg_100a property:indic_nrg indic_nrg:B_101932 .
	  _:nrg_100a sdmx-measure:obsValue ?B_101932 .
	} UNION { 
          _:nrg_100a property:indic_nrg indic_nrg:B_101940 .
    	  _:nrg_100a sdmx-measure:obsValue ?B_101940 .
	} UNION { 
        _:nrg_100a property:indic_nrg ?indic_nrg . 
        FILTER (?indic_nrg IN (indic_nrg:B_100800,indic_nrg:B_101910,
                indic_nrg:B_101920, indic_nrg:B_101932,indic_nrg:B_101931,
                indic_nrg:B_101940))
	_:nrg_100a sdmx-measure:obsValue ?total .
     }
    }}
  } UNION {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_102a.rdf.gz> { 
    {
    _:nrg_102a sdmx-dimension:refArea ?geo .
    _:nrg_102a sdmx-attribute:unitMeasure unit:TJ .
    _:nrg_102a sdmx-dimension:timePeriod ?date .
    { 
      _:nrg_102a property:indic_nrg indic_nrg:B_101920 .
      {
        _:nrg_102a property:product ?product . 
        FILTER (?product in (product:3234, product:3260, product:3220))
        _:nrg_102a sdmx-measure:obsValue ?road .
      }
    } UNION {
      _:nrg_102a property:indic_nrg indic_nrg:B_101910 .
      {
        _:nrg_102a property:product ?product . 
        FILTER (?product in (product:3260, product:3270A))
        _:nrg_102a sdmx-measure:obsValue ?rail .
      }
    } UNION {
      _:nrg_102a property:indic_nrg ?indic_nrg . 
      FILTER (?indic_nrg IN (indic_nrg:B_101931,indic_nrg:B_101932))
      {
        _:nrg_102a property:product ?product . 
        FILTER (?product in (product:3235, product:3247))
        _:nrg_102a sdmx-measure:obsValue ?aviation .
      }
    }  UNION {
      _:nrg_102a property:indic_nrg ?indic_nrg . 
      FILTER (?indic_nrg IN (indic_nrg:B_101940,indic_nrg:B_100800))
      {
        _:nrg_102a property:product ?product . 
        FILTER (?product in (product:3260, product:3270A, product:3234))
        _:nrg_102a sdmx-measure:obsValue ?ship .
      }
    }
   }}
  } UNION {
     GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_105a.rdf.gz> { 
      {
        _:nrg_105a sdmx-dimension:refArea ?geo .

        _:nrg_105a sdmx-attribute:unitMeasure unit:TJ .
        _:nrg_105a sdmx-dimension:timePeriod ?date .
        _:nrg_105a property:indic_nrg indic_nrg:B_101920 .
        _:nrg_105a property:product product:6000 .
        _:nrg_105a sdmx-measure:obsValue ?B_101920_el .
      }
     }
  }} 
  FILTER (?geo in (geo:EU28))
}
GROUP BY ?date 
ORDER BY ?date