Change in Final Energy Consumption by Transport Mode, EU13, 1990-2016

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>
PREFIX indic_nrg: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_nrg/>
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT 
?indic_nrg_label as ?indic_nrg
'EU-13' as ?ugeo
round((( SUM(?last_year)-SUM(?first_year) ) / SUM(?first_year) )*1000)/10.0 as ?obsValue
{{

  SELECT DISTINCT
  bif:either(?indic_nrg in (indic_nrg:B_101931, indic_nrg:B_101932), 'Air Domestic/International', ?indic_nrg_label) as ?indic_nrg_label
 bif:either(year(?date) = 1990, SUM(?obsValue), 0) as ?first_year
  bif:either(year(?date) = 2016, SUM(?obsValue), 0) as ?last_year

  WHERE {
  {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_102a.rdf.gz> 
      { 
        _:nrg_102a sdmx-dimension:timePeriod ?date .
        _:nrg_102a sdmx-attribute:unitMeasure unit:TJ .
        _:nrg_102a sdmx-dimension:refArea ?geo .
        _:nrg_102a property:product ?product . 
        FILTER (?product in (product:3220, product:3234, product:3235,
                             product:3246, product:3247, product:3260,
                             product:3270A))
        _:nrg_102a property:indic_nrg ?indic_nrg .
        _:nrg_102a sdmx-measure:obsValue ?obsValue .
   }
    } UNION {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_103a.rdf.gz> 
      { 
        _:nrg_103a sdmx-dimension:timePeriod ?date .
        _:nrg_103a sdmx-attribute:unitMeasure unit:TJ .
        _:nrg_103a sdmx-dimension:refArea ?geo .
        _:nrg_103a property:product product:4100 . 
        _:nrg_103a property:indic_nrg ?indic_nrg .
        _:nrg_103a sdmx-measure:obsValue ?obsValue .
   }
   } UNION {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_105a.rdf.gz> 
      { 
        _:nrg_105a sdmx-dimension:timePeriod ?date .
        _:nrg_105a sdmx-attribute:unitMeasure unit:TJ .
        _:nrg_105a sdmx-dimension:refArea ?geo .
        _:nrg_105a property:product product:6000 . 
        _:nrg_105a property:indic_nrg ?indic_nrg .
        _:nrg_105a sdmx-measure:obsValue ?obsValue .
   }
   } UNION {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_107a.rdf.gz> 
      { 
        _:nrg_107a sdmx-dimension:timePeriod ?date .
        _:nrg_107a sdmx-attribute:unitMeasure unit:TJ .
        _:nrg_107a sdmx-dimension:refArea ?geo .
        _:nrg_107a property:product ?product . 
        FILTER (?product in (product:5541, product:5542, product:5546,
                             product:5547, product:5548))
        _:nrg_107a property:indic_nrg ?indic_nrg .
        _:nrg_107a sdmx-measure:obsValue ?obsValue .
   }

   } 
   FILTER (?geo in (geo:BG, geo:CY, geo:CZ, geo:EE, geo:HR, geo:HU, geo:LT, geo:LV, geo:MT, geo:PL, geo:RO, geo:SI, geo:SK))
   ?geo rdfs:label ?ugeo .
   FILTER (?indic_nrg in (indic_nrg:B_101931, indic_nrg:B_101932, 
                          indic_nrg:B_100800, indic_nrg:B_101910, 
                          indic_nrg:B_101920, indic_nrg:B_101940)) 
   ?indic_nrg rdfs:label ?indic_nrg_label .
  }

}}
GROUP BY ?indic_nrg_label