Data table via SPARQL

CO2-emission intensity from electricity generation

Data table via SPARQL Published 12 Dec 2016 Last modified 14 Dec 2016

This is an old version, kept for reference only.

Go to latest version

Data visualisations

Menu

Download this dataset

Formats suitable for human consumption

HTML CSV TSV

Formats suitable for machine-to-machine communication

JSON Exhibit JSON XML XML with Schema

Dataset preview

(Live Query)

date	ugeo	type	obsValue
"1990"^^<http://www.w3.org/2001/XMLSchema#int>	"Austria"	"Electricity generation"	"195.6"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1991"^^<http://www.w3.org/2001/XMLSchema#int>	"Austria"	"Electricity generation"	"204.1"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1992"^^<http://www.w3.org/2001/XMLSchema#int>	"Austria"	"Electricity generation"	"149.4"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1993"^^<http://www.w3.org/2001/XMLSchema#int>	"Austria"	"Electricity generation"	"130.3"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1994"^^<http://www.w3.org/2001/XMLSchema#int>	"Austria"	"Electricity generation"	"140.5"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1995"^^<http://www.w3.org/2001/XMLSchema#int>	"Austria"	"Electricity generation"	"146.8"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1996"^^<http://www.w3.org/2001/XMLSchema#int>	"Austria"	"Electricity generation"	"154.9"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1997"^^<http://www.w3.org/2001/XMLSchema#int>	"Austria"	"Electricity generation"	"158.6"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1998"^^<http://www.w3.org/2001/XMLSchema#int>	"Austria"	"Electricity generation"	"138.3"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1999"^^<http://www.w3.org/2001/XMLSchema#int>	"Austria"	"Electricity generation"	"130"^^<http://www.w3.org/2001/XMLSchema#decimal>

Received 699 rows in 0.016 seconds.

JSON Url:
https://eea.europa.eu./data-and-maps/daviz/sds/co2-emission-intensity-from-electricity-generation/daviz.json

For system integrators

Linked Data query (SPARQL)

The following info can be used by a system developer / database administrator in order to retrieve this dataset programmatically over the web using a SPARQL client.

Are you new to Linked Data technology? visit http://linkeddata.org

SPARQL Endpoint:
http://semantic.eea.europa.eu/sparql

SPARQL Query:


        PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>
PREFIX indic_nrg: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_nrg/>
PREFIX clrtap_nec_unfccc: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/schema/>
PREFIX sector: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/unfccc_crf_sector/>
PREFIX unfccc_geo: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/country/>
PREFIX common_countries: <http://dd.eionet.europa.eu/vocabulary/common/countries/>

SELECT 
?date
?ugeo
'Electricity generation' as ?type
round((?den/?nom)*10000)/10.0  as ?obsValue
{{

SELECT DISTINCT
year(xsd:date(?date)) as ?date
?ugeo
( sum(?nrg_105a_101121) + sum(?nrg_105a_101122) + sum(?nrg_105a_101102 ) + sum(?nrg_105a_101200) ) / 86 as ?nom

( ( ( sum(?nrg_110a_6000)/ ( sum(?nrg_110a_5200) + sum(?nrg_110a_6000) + sum(?nrg_106a) ) ) * sum(?unfccc_crf) /1000 ) + ( ( ( sum(?nrg_110a_6000)/ ( sum(?nrg_110a_5200) + sum(?nrg_110a_6000) + sum(?nrg_106a) ) ) * sum(?unfccc_crf) / sum(?nrg_105a_101121) ) * sum(?nrg_105a_101122) /1000 ) ) as ?den

WHERE {
  {
  GRAPH <http://r.eionet.europa.eu/rdfdumps/clrtap_nec_unfccc/unfccc_crf.rdf.gz> 
    {
      _:unfccc_crf clrtap_nec_unfccc:country_code ?geo .
       _:unfccc_crf clrtap_nec_unfccc:year ?date .
      FILTER (?date != '1985-1987')
      {
        _:unfccc_crf clrtap_nec_unfccc:unit 'Gg' .
        _:unfccc_crf clrtap_nec_unfccc:pollutant_name 'CO2' .         
        _:unfccc_crf clrtap_nec_unfccc:sector_code sector:1.A.1.a . 
        _:unfccc_crf clrtap_nec_unfccc:emissions ?unfccc_crf .
      }
    }
   } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_105a.rdf.gz>
    {
      _:nrg_105a sdmx-dimension:timePeriod ?date . 
      _:nrg_105a sdmx-dimension:refArea ?geo . 
      _:nrg_105a property:product product:6000 .
      _:nrg_105a sdmx-attribute:unitMeasure unit:KTOE .
      _:nrg_105a sdmx-measure:obsValue ?nrg_105a .
      {
        _:nrg_105a property:indic_nrg indic_nrg:B_101121 .
        _:nrg_105a sdmx-measure:obsValue ?nrg_105a_101121 .
      } UNION {      
        _:nrg_105a property:indic_nrg indic_nrg:B_101122 .
        _:nrg_105a sdmx-measure:obsValue ?nrg_105a_101122 .
      } UNION {      
        _:nrg_105a property:indic_nrg indic_nrg:B_101102 .
        _:nrg_105a sdmx-measure:obsValue ?nrg_105a_101102 .
      } UNION {      
        _:nrg_105a property:indic_nrg indic_nrg:B_101200 .
        _:nrg_105a sdmx-measure:obsValue ?nrg_105a_101200 .
      }
     }
  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_106a.rdf.gz>
    {
      _:nrg_106a sdmx-dimension:timePeriod ?date . 
      _:nrg_106a property:indic_nrg indic_nrg:B_101109 .
      _:nrg_106a sdmx-dimension:refArea ?geo . 
      _:nrg_106a property:product product:5200 .
      _:nrg_106a sdmx-attribute:unitMeasure unit:KTOE .
      _:nrg_106a sdmx-measure:obsValue ?nrg_106a .
     }
  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_110a.rdf.gz>
    {
      _:nrg_110a sdmx-dimension:timePeriod ?date .
      _:nrg_110a sdmx-attribute:unitMeasure unit:KTOE .
      _:nrg_110a sdmx-dimension:refArea ?geo .
      _:nrg_110a property:indic_nrg indic_nrg:B_101121 .
      {
        _:nrg_110a property:product product:6000 .
        _:nrg_110a sdmx-measure:obsValue ?nrg_110a_6000 .
      } UNION {      
        _:nrg_110a property:product product:5200 .
        _:nrg_110a sdmx-measure:obsValue ?nrg_110a_5200 .
      }
    } 
  }
  ?geo skos:exactMatch ?eeauri .
  ?eeauri skos:inScheme common_countries: .
  ?eeauri rdfs:label ?ugeo .
  FILTER (year(xsd:date(?date)) >= 1990)
  FILTER (?ugeo != 'Turkey' && ?ugeo != 'Norway' && 
          ?ugeo != 'Lichtenstein' && ?ugeo != 'Switzerland' 
          && ?ugeo != 'Iceland' )

}
GROUP BY year(xsd:date(?date)) ?ugeo
HAVING ( sum(?unfccc_crf) ) > 0
}}
ORDER BY ?ugeo ?date