Per capita household expenditure on food and clothing and disposable income in European countries, 2012

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX coicop: <http://rdfdata.eionet.europa.eu/eurostat/dic/coicop#>
PREFIX unit: <http://rdfdata.eionet.europa.eu/eurostat/dic/unit#>
PREFIX geo: <http://rdfdata.eionet.europa.eu/eurostat/dic/geo#>
PREFIX sex: <http://purl.org/linked-data/sdmx/2009/code#>
PREFIX age: <http://rdfdata.eionet.europa.eu/eurostat/dic/age#>
PREFIX sector: <http://rdfdata.eionet.europa.eu/eurostat/dic/sector#>
PREFIX indic_na: <http://rdfdata.eionet.europa.eu/eurostat/dic/indic_na#>
PREFIX direct: <http://dd.eionet.europa.eu/vocabulary/eurostat/direct/>

SELECT DISTINCT
?ugeo
sum(?nasa_nf_tr) as ?nasa_nf_tr
sum(?demo_pjan) as ?demo_pjan
sum(?nama_co3_c_food) as ?nama_co3_c_food
sum(?nama_co3_c_clothing) as ?nama_co3_c_clothing

round(sum(?nama_co3_c_food) / sum(?demo_pjan)*1000000) as ?food_per_capita
round(sum(?nama_co3_c_clothing) / sum(?demo_pjan)*1000000) as ?clothing_per_capita
round(sum(?nasa_nf_tr) / sum(?demo_pjan)*1000000) as ?household_disposable_income_per_capita

WHERE {
{
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nama_co3_c.rdf.gz> 
   {
     _:nama_co3_c sdmx-dimension:timePeriod ?date .
     _:nama_co3_c sdmx-dimension:refArea ?geo . 
     
     _:nama_co3_c sdmx-attribute:unitMeasure unit:MIO_EUR .
     {
       _:nama_co3_c property:coicop coicop:CP011 .
       _:nama_co3_c sdmx-measure:obsValue ?nama_co3_c_food .
     } union {
       _:nama_co3_c property:coicop coicop:CP031 .
       _:nama_co3_c sdmx-measure:obsValue ?nama_co3_c_clothing .
     }
   }
  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/demo_pjan.rdf.gz> 
   {
     _:demo_pjan sdmx-dimension:timePeriod ?date .
     _:demo_pjan sdmx-dimension:refArea ?geo .
     _:demo_pjan sdmx-dimension:age age:TOTAL .
     _:demo_pjan sdmx-dimension:sex sex:sex-T .
     _:demo_pjan sdmx-measure:obsValue ?demo_pjan .

   }
  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nasa_nf_tr.rdf.gz> 
   {
     _:nasa_nf_tr sdmx-dimension:timePeriod ?date . 
     _:nasa_nf_tr property:sector sector:S14_S15 .
     _:nasa_nf_tr property:direct direct:RECV .
     _:nasa_nf_tr property:indic_na indic_na:B6G .
     _:nasa_nf_tr sdmx-dimension:refArea ?geo .
     _:nasa_nf_tr sdmx-attribute:unitMeasure unit:MIO_EUR .
     _:nasa_nf_tr sdmx-measure:obsValue ?nasa_nf_tr .
   }
  }
 FILTER (year(?date) = 2012)
 #?geo rdfs:label ?ugeo 
 ?geo skos:notation ?ugeo 
 }
GROUP BY ?ugeo ?geo
HAVING sum(?nasa_nf_tr) > 0 and sum(?nama_co3_c_food) > 0 and sum(?nama_co3_c_clothing) > 0
ORDER BY ?ugeo