Historic and projected trends of GHG emissions-distance to target

PREFIX clrtap_nec_unfccc: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/schema/>
PREFIX geo: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/country/>
PREFIX sector: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/unfccc_crf_sector/>
PREFIX rdf-schema: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ghg_projections: <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/ghg_projections_092013.tsv#>
PREFIX CP1_targets_EU28: <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/CP1_targets_for_EU28_052014.tsv#>
PREFIX CP1_targets_EU15: <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/CP1_targets_for_EU15_052014.tsv#>

SELECT
xsd:integer(?year) as ?year

round(sum(?unfccc_crf_eu28)/1000) as ?GHG_eu28
round(sum(?unfccc_crf_eu15)/1000) as ?GHG_eu15
round((sum(?unfccc_crf_eu28) - sum(?unfccc_crf_eu15))/1000) as ?GHG_difference
round(sum(?ghg_projections)/1000) as ?ghg_projections
round(sum(?CP1_targets_eu15)) as ?CP1_targets_eu15
round(sum(?CP1_targets_eu28)) as ?CP1_targets_eu28

round(sum(?CP1_targets_eu28) - (sum(?unfccc_crf_eu28)/1000)) as ?CP1_targets_difference

WHERE {
  { 
    GRAPH <http://r.eionet.europa.eu/rdfdumps/clrtap_nec_unfccc/unfccc_crf.rdf.gz> 
    {
      _:unfccc_crf clrtap_nec_unfccc:unit ?unit . FILTER (?unit = 'Gg CO2 equivalent')
      _:unfccc_crf clrtap_nec_unfccc:sector_code ?sector_code . 
      FILTER (?sector_code in (sector:1, sector:2, sector:3, sector:4, sector:6, sector:7))
      _:unfccc_crf clrtap_nec_unfccc:pollutant_name ?pollutant_name . 
      FILTER (?pollutant_name = 'All greenhouse gases - (CO2 equivalent)')
      _:unfccc_crf clrtap_nec_unfccc:year ?year . FILTER (?year != ('KPBY'))

      {
        _:unfccc_crf clrtap_nec_unfccc:country_code ?geo . FILTER (?geo in (geo:EU28))
        _:unfccc_crf clrtap_nec_unfccc:emissions ?unfccc_crf_eu28 .
      } UNION {
        _:unfccc_crf clrtap_nec_unfccc:country_code ?geo . FILTER (?geo in (geo:EU15))
        _:unfccc_crf clrtap_nec_unfccc:emissions ?unfccc_crf_eu15 .
      }
    }
  } UNION {

    GRAPH <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/ghg_projections_092013.tsv> 
    {
      _:ghg_projections ghg_projections:country ?country  .
      _:ghg_projections ghg_projections:year ?year . FILTER (xsd:integer(?year) > 2012)
      _:ghg_projections ghg_projections:value ?ghg_projections .
    } 
  } UNION {
    GRAPH <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/CP1_targets_for_EU28_052014.tsv> 
    {
      _:CP1_targets_EU28 CP1_targets_EU28:geo ?geo .
      _:CP1_targets_EU28 CP1_targets_EU28:year ?year .
      _:CP1_targets_EU28 CP1_targets_EU28:value ?CP1_targets_eu28 .
    } 
  } UNION {
    GRAPH <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/CP1_targets_for_EU15_052014.tsv> 
    {
      _:CP1_targets_EU15 CP1_targets_EU15:geo ?geo .
      _:CP1_targets_EU15 CP1_targets_EU15:year ?year .
      _:CP1_targets_EU15 CP1_targets_EU15:value ?CP1_targets_eu15 .
    } 
  }
}
GROUP BY xsd:integer(?year)
ORDER BY xsd:integer(?year)