Do something for our planet, print this page only if needed. Even a small action can make an enormous difference when millions of people do it!
Data table via SPARQL
Received 90 rows in 0.030 seconds.
The following info can be used by a system developer / database administrator in order to retrieve this dataset programmatically over the web using a SPARQL client.
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#>
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#>
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX indic_ag: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_ag/>
PREFIX itm_newa: <http://dd.eionet.europa.eu/vocabulary/eurostat/itm_newa/>
PREFIX indic_ef: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_ef/>
PREFIX irrig: <http://dd.eionet.europa.eu/vocabulary/eurostat/irrig/>
PREFIX agrarea: <http://dd.eionet.europa.eu/vocabulary/eurostat/agrarea/>
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX wat_proc: <http://dd.eionet.europa.eu/vocabulary/eurostat/wat_proc/>
PREFIX wat_src: <http://dd.eionet.europa.eu/vocabulary/eurostat/wat_src/>
PREFIX countries: <http://dd.eionet.europa.eu/vocabulary/common/countries/>
PREFIX crops: <http://dd.eionet.europa.eu/vocabulary/eurostat/crops/>
PREFIX strucpro: <http://dd.eionet.europa.eu/vocabulary/eurostat/strucpro/>
PREFIX swbewa2017: <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/WREI004/2017/swbewa2017.tsv#>
PREFIX fadn2017: <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/WREI004/2017/fadn2017.tsv#>
PREFIX env_wat_abs_abs_nace_A011_A013: <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/WREI004/2017/env_wat_abs_abs_nace_A011_A013.tsv#>
SELECT DISTINCT
year(?date) as ?timePeriod
?geo as ?refArea
year(?date) as ?date
?ugeo
bif:either(?geo in (geo:AL, geo:CY, geo:EL, geo:ES, geo:IT, geo:ME, geo:MT, geo:PT, geo:TR), 'Southern',
bif:either(?geo in (geo:AT, geo:BE, geo:CH, geo:DE, geo:DK, geo:FR, geo:IE, geo:LI, geo:LU, geo:NL, geo:UK, geo:SE, geo:FI, geo:IS, geo:NO), 'Western',
'Eastern')) as ?region
round(( ( sum(?10000_PPS) - (sum(?19010_PPS) + sum(?19040_PPS) + (sum(?19020_PPS) * (sum(?10000_PPS)/sum(?16000_PPS))) + (sum(?19030_PPS) * (sum(?10000_PPS)/(sum(?10000_PPS)+sum(?13000_PPS))))) ) * (1.0-sum(xsd:double(?fadn2017))) / sum(xsd:double(?AGRAREA_HA)))*100000.0)/100.0 as ?profit
round(( sum(xsd:double(?abs_nace_A011_A013)) + sum(coalesce(?env_wat_use,0)) + sum(xsd:double(?swbewa2017)) ) / sum(xsd:double(?AGRAREA_HA))*10000.0)/10.0 as ?water
round(sum(?ef_poirrig) / sum(xsd:double(?AGRAREA_HA))/1000.0 *10000)/100.0 as ?share_irrigated_area
WHERE {{
{
GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/env_wat_abs.rdf.gz> {
_:env_wat_abs sdmx-dimension:timePeriod ?date .
_:env_wat_abs sdmx-dimension:refArea ?geo .
_:env_wat_abs sdmx-attribute:unitMeasure unit:MIO_M3 .
_:env_wat_abs property:wat_src wat_src:FRW .
_:env_wat_abs property:wat_proc wat_proc:ABS_AGR_IR .
_:env_wat_abs sdmx-measure:obsValue ?env_wat_abs .
}
} UNION {
GRAPH <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/WREI004/2017/env_wat_abs_abs_nace_A011_A013.tsv>
{
_:abs_nace_A011_A013 env_wat_abs_abs_nace_A011_A013:geo ?geo .
_:abs_nace_A011_A013 env_wat_abs_abs_nace_A011_A013:date ?date .
_:abs_nace_A011_A013 env_wat_abs_abs_nace_A011_A013:obsValue ?abs_nace_A011_A013 .
}
} UNION {
GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/ef_poirrig.rdf.gz>
{
_:ef_poirrig sdmx-dimension:timePeriod ?date .
_:ef_poirrig sdmx-dimension:refArea ?geo .
_:ef_poirrig property:irrig irrig:TOTAL .
_:ef_poirrig property:indic_ef ?indic_ef .
FILTER (?indic_ef IN (indic_ef:B_6_2_2_HA, indic_ef:B_4_7_7_2_8_2_HA))
_:ef_poirrig sdmx-measure:obsValue ?ef_poirrig .
}
} UNION {
GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/env_wat_use.rdf.gz> {
_:env_wat_use sdmx-dimension:timePeriod ?date .
_:env_wat_use sdmx-dimension:refArea ?geo .
_:env_wat_use property:wat_proc wat_proc:ABS_AGR_IR .
_:env_wat_use sdmx-attribute:unitMeasure unit:MIO_M3 .
_:env_wat_use property:wat_src ?wat_src .
FILTER (?wat_src in (wat_src:RUW, wat_src:DSW, wat_src:NFW))
_:env_wat_use sdmx-measure:obsValue ?env_wat_use .
}
} UNION {
GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/apro_acs_a.rdf.gz>
{
_:apro_acs_a sdmx-dimension:timePeriod ?date .
_:apro_acs_a property:crops ?crops .
FILTER (?crops in (crops:ARA, crops:PECR))
_:apro_acs_a sdmx-dimension:refArea ?geo .
_:apro_acs_a property:strucpro strucpro:MA .
_:apro_acs_a sdmx-measure:obsValue ?apro_acs_a .
_:apro_acs_a sdmx-measure:obsValue ?AGRAREA_HA .
}
} UNION {
GRAPH <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/WREI004/2017/swbewa2017.tsv>
{
_:swbewa2017 swbewa2017:date ?date .
_:swbewa2017 swbewa2017:geo ?geo .
_:swbewa2017 swbewa2017:obsValue ?swbewa2017 .
}
} UNION {
GRAPH <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/WREI004/2017/fadn2017.tsv>
{
_:fadn2017 fadn2017:date ?date .
_:fadn2017 fadn2017:geo ?geo .
_:fadn2017 fadn2017:obsValue ?fadn2017 .
}
} UNION {
GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/aact_eaa07.rdf.gz> {
_:aact_eaa07_PPS sdmx-dimension:timePeriod ?date .
_:aact_eaa07_PPS sdmx-dimension:refArea ?geo .
_:aact_eaa07_PPS sdmx-attribute:unitMeasure unit:MIO_PPS .
_:aact_eaa07_PPS property:indic_ag indic_ag:PROD_BP .
{
_:aact_eaa07_PPS property:itm_newa itm_newa:19010 .
_:aact_eaa07_PPS sdmx-measure:obsValue ?19010_PPS .
} UNION {
_:aact_eaa07_PPS property:itm_newa itm_newa:19040 .
_:aact_eaa07_PPS sdmx-measure:obsValue ?19040_PPS .
} UNION {
_:aact_eaa07_PPS property:itm_newa itm_newa:19020.
_:aact_eaa07_PPS sdmx-measure:obsValue ?19020_PPS .
} UNION {
_:aact_eaa07_PPS property:itm_newa itm_newa:19030.
_:aact_eaa07_PPS sdmx-measure:obsValue ?19030_PPS .
} UNION {
_:aact_eaa07_PPS property:itm_newa itm_newa:13000.
_:aact_eaa07_PPS sdmx-measure:obsValue ?13000_PPS .
} UNION {
_:aact_eaa07_PPS property:itm_newa itm_newa:10000.
_:aact_eaa07_PPS sdmx-measure:obsValue ?10000_PPS .
} UNION {
_:aact_eaa07_PPS property:itm_newa itm_newa:16000.
_:aact_eaa07_PPS sdmx-measure:obsValue ?16000_PPS .
}
}
}
?geo skos:notation ?geoNotation .
?geo skos:exactMatch ?eeauri .
?eeauri skos:inScheme countries: .
?eeauri rdfs:label ?ugeo .
FILTER (strlen(?geoNotation) = 2)
#FILTER (?geo = geo:DK)
FILTER (year(?date) in (2005, 2007, 2010, 2013))
}}
GROUP BY ?geo ?ugeo year(?date)
HAVING ( sum(xsd:double(?abs_nace_A011_A013)) + sum(coalesce(?env_wat_use,0)) + sum(xsd:double(?swbewa2017)) ) / sum(?AGRAREA_HA) > 0 && round(( ( sum(?10000_PPS) - (sum(?19010_PPS) + sum(?19040_PPS) + (sum(?19020_PPS) * (sum(?10000_PPS)/sum(?16000_PPS))) + (sum(?19030_PPS) * (sum(?10000_PPS)/(sum(?10000_PPS)+sum(?13000_PPS))))) ) * (1.0-sum(xsd:double(?fadn2017))) / sum(?AGRAREA_HA))*1000.0) > 0
ORDER BY ?ugeo ?date
For references, please go to https://eea.europa.eu./data-and-maps/daviz/sds/economic-profit-rom-crops-vs or scan the QR code.
PDF generated on 23 Nov 2024, 08:29 AM
Engineered by: EEA Web Team
Software updated on 26 September 2023 08:13 from version 23.8.18
Software version: EEA Plone KGS 23.9.14
Document Actions
Share with others