Relative importance of aquaculture production type by continent

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX tableFile: <http://semantic.eea.europa.eu/project/CSI033/FishStatUnpivot.csv#>
PREFIX countrygroups: <http://dd.eionet.europa.eu/vocabulary/common/countrygroups/>
PREFIX countries: <http://dd.eionet.europa.eu/vocabulary/common/countries/>

SELECT
?year
?geoarea
?group
?environment
sum(xsd:decimal(?obsValue)) as ?obsValue
{{
  SELECT DISTINCT
    ?year
    ?geoarea
    ?group
    bif:either(?environment = 'Brackishwater', 'Marine', ?environment) as ?environment
    sum(xsd:decimal(?obsValue))/1000 as ?obsValue

  WHERE {
    _:rec tableFile:country ?country .
    _:rec tableFile:continent ?continent .
    _:rec tableFile:iso2 ?iso2 .
    _:rec tableFile:speciesGroup ?speciesGroup .
    _:rec tableFile:species ?species .
    _:rec tableFile:group ?group .
    _:rec tableFile:area ?area .
    _:rec tableFile:environment ?environment .
    _:rec tableFile:unit ?unit .
    _:rec tableFile:year ?year .
    {
      _:rec tableFile:continent ?geoarea .
      FILTER (?geoarea != 'Europe')
      _:rec tableFile:obsValue ?obsValue .
    } UNION {
      ?member skos:notation ?iso2 .
      ?geoarea_uri skos:member ?member.
      ?geoarea_uri ?o countrygroups: .
      ?geoarea_uri skos:notation ?geoarea .
      _:rec tableFile:obsValue ?obsValue .
      FILTER (?geoarea_uri in (countrygroups:EU28 ))
    } UNION {
      { SELECT 'EEA39' as ?geoarea {} } .
      ?member skos:notation ?iso2 .
      ?geoarea_uri skos:member ?member.
      ?geoarea_uri ?o countrygroups: .
      _:rec tableFile:obsValue ?obsValue .
      FILTER (?geoarea_uri in (countrygroups:EEA33) || 
              ?member in (countries:AL, countries:BA, countries:MK, 
              countries:ME, countries:RS, countries:XK, countries:CS))
    }
    FILTER (?group in ('PLANTAE AQUATICAE', 'CRUSTACEA', 'PISCES', 'MOLLUSCA'))
    FILTER (?year = 2015)
  }
  GROUP BY ?year ?group ?environment ?geoarea
}}
ORDER BY ?group ?geoarea