Primary energy consumption by fuel

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX indic_nrg: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_nrg/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX product:	<http://dd.eionet.europa.eu/vocabulary/eurostat/product/>

SELECT 
year(?date) as ?year
round(sum(?all_products)/1000) as ?all_products
round(sum(?solid_fuels)/1000)  as ?solid_fuels
round(sum(?total_petroleum_products)/1000) as ?total_petroleum_products
round(sum(?gas)/1000) as ?gas
round(sum(?nuclear_heat)/1000) as ?nuclear_heat
round(sum(?renewable_energies)/1000) as ?renewable_energies
round((sum(?electrical_energy)+sum(?derived_heat)+sum(?industrial_wastes))/1000) as ?others

round(sum(?electrical_energy)/1000) as ?electrical_energy
round(sum(?derived_heat)/1000) as ?derived_heat
round(sum(?industrial_wastes)/1000) as ?industrial_wastes

WHERE {
{  
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_100a.rdf.gz> 
  {
  _:nrg_100a sdmx-dimension:timePeriod ?date . 
  _:nrg_100a property:indic_nrg indic_nrg:B_100900 . 
  _:nrg_100a sdmx-dimension:refArea geo:EU28 . 
  _:nrg_100a sdmx-attribute:unitMeasure unit:1000TOE . 

  {
    _:nrg_100a property:product product:0000 . 
    _:nrg_100a sdmx-measure:obsValue ?all_products .
  } UNION {
    _:nrg_100a property:product product:2000 . 
    _:nrg_100a sdmx-measure:obsValue ?solid_fuels .
  } UNION {
    _:nrg_100a property:product product:3000 . 
    _:nrg_100a sdmx-measure:obsValue ?total_petroleum_products .
  } UNION {
    _:nrg_100a property:product product:4000 . 
    _:nrg_100a sdmx-measure:obsValue ?gas .
  } UNION {
    _:nrg_100a property:product product:5100 . 
    _:nrg_100a sdmx-measure:obsValue ?nuclear_heat .
  } UNION {
    _:nrg_100a property:product product:6000 . 
    _:nrg_100a sdmx-measure:obsValue ?electrical_energy .
  } UNION {
    _:nrg_100a property:product product:5200 . 
    _:nrg_100a sdmx-measure:obsValue ?derived_heat .
  } UNION {
    _:nrg_100a property:product product:5500 . 
    _:nrg_100a sdmx-measure:obsValue ?renewable_energies .
  }
  } 

  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_108a.rdf.gz> 
  {
  _:nrg_108a property:geo geo:EU28 .
  _:nrg_108a property:unit unit:1000TOE .
  _:nrg_108a sdmx-dimension:timePeriod ?date .
  _:nrg_108a property:indic_nrg indic_nrg:B_100900 .
  _:nrg_108a property:product product:7100 .
  _:nrg_108a sdmx-measure:obsValue ?industrial_wastes .
  }
 }

} 
GROUP BY year(?date)
ORDER BY ?date