Final energy consumption of fuel type for other sectors

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#>
PREFIX siec: <http://dd.eionet.europa.eu/vocabulary/eurostat/siec/>
PREFIX nrg_bal: <http://dd.eionet.europa.eu/vocabulary/eurostat/nrg_bal/>
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>

SELECT DISTINCT
year(?date) as ?date
?siec_label
"other" as ?nrg_bal_label

round(((sum(?FC_OTH_E)-sum(?FC_OTH_HH_E)-sum(?FC_OTH_CP_E))/sum(xsd:double(?nrg_bal_total)))*10000)/100.0 as ?share

round((sum(?FC_OTH_E)-sum(?FC_OTH_HH_E)-sum(?FC_OTH_CP_E))/100)/10.0 as ?obsValue
round(sum(?nrg_bal_total )/100)/10.0 as ?obsValue_total

WHERE { 
 GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_bal_c.rdf.gz> {
    ?nrg_bal_c sdmx-dimension:refArea geo:EU28 .
    ?nrg_bal_c sdmx-attribute:unitMeasure unit:KTOE .
    ?nrg_bal_c sdmx-dimension:timePeriod ?date .
    ?nrg_bal_c property:siec ?siec .
    FILTER (?siec in (siec:C0000X0350-0370, siec:O4000XBIO, siec:G3000, 
                      siec:E7000, siec:TOTAL))

    {
       ?nrg_bal_c property:nrg_bal nrg_bal:FC_OTH_E .
       ?nrg_bal_c sdmx-measure:obsValue ?FC_OTH_E  .
    } UNION {
       ?nrg_bal_c property:nrg_bal nrg_bal:FC_OTH_HH_E .
       ?nrg_bal_c sdmx-measure:obsValue ?FC_OTH_HH_E .
    } UNION {
       ?nrg_bal_c property:nrg_bal nrg_bal:FC_OTH_CP_E .
       ?nrg_bal_c sdmx-measure:obsValue ?FC_OTH_CP_E .
    }

    ?nrg_bal_c_total sdmx-dimension:refArea geo:EU28 .
    ?nrg_bal_c_total sdmx-attribute:unitMeasure unit:KTOE .
    ?nrg_bal_c_total sdmx-dimension:timePeriod ?date .
    ?nrg_bal_c_total property:nrg_bal nrg_bal:FC_E .
    ?nrg_bal_c_total property:siec ?siec .
    ?nrg_bal_c_total sdmx-measure:obsValue ?nrg_bal_total .

  }
  ?siec rdfs:label ?siec_label .
}
ORDER BY ?date ?siec_label