Contribution of renewable energy sources to primary energy consumption

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX g: <http://rdfdata.eionet.europa.eu/eurostat/dic/geo#>
PREFIX u: <http://rdfdata.eionet.europa.eu/eurostat/dic/unit#>
PREFIX p: <http://rdfdata.eionet.europa.eu/eurostat/dic/product#>
PREFIX indic_nrg: <http://rdfdata.eionet.europa.eu/eurostat/dic/indic_nrg#>

SELECT 
year(?date) as ?year

(round((sum(?nrg_1071a_5530)/sum(?nrg_100a))*1000))/10.0 as ?solar
(round((sum(?nrg_1072a_5520)/sum(?nrg_100a))*1000))/10.0 as ?wind
(round((sum(?nrg_1071a_5550)/sum(?nrg_100a))*1000))/10.0 as ?geothermal
(round((sum(?nrg_1072a_5510)/sum(?nrg_100a))*1000))/10.0 as ?hydro
(round((sum(?nrg_1071a_5540)/sum(?nrg_100a))*1000))/10.0 as ?biomass_and_waste

WHERE {
{  
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_100a.rdf.gz> 
  {
  _:nrg_100a property:geo g:EU27 .
  _:nrg_100a property:unit u:1000TOE .
  _:nrg_100a sdmx-dimension:timePeriod ?date .
  _:nrg_100a property:indic_nrg indic_nrg:B_100900 .
  _:nrg_100a sdmx-measure:obsValue ?nrg_100a .
  }

  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_1072a.rdf.gz> 
  {
  _:nrg_1072a property:geo g:EU27 .
  _:nrg_1072a property:unit u:1000TOE .
  _:nrg_1072a sdmx-dimension:timePeriod ?date .
  _:nrg_1072a property:indic_nrg indic_nrg:B_100900 .
    { 
      _:nrg_1072a property:product p:5510 .
      _:nrg_1072a sdmx-measure:obsValue ?nrg_1072a_5510 .
    } UNION {
      _:nrg_1072a property:product p:5520 .
      _:nrg_1072a sdmx-measure:obsValue ?nrg_1072a_5520 .
    } 
  }
} UNION {
  
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_1071a.rdf.gz> 
  {
  _:nrg_1071a property:geo g:EU27 .
  _:nrg_1071a property:unit u:1000TOE .
  _:nrg_1071a sdmx-dimension:timePeriod ?date .
  _:nrg_1071a property:indic_nrg indic_nrg:B_100900 .
    { 
      _:nrg_1071a property:product p:5530.
      _:nrg_1071a sdmx-measure:obsValue ?nrg_1071a_5530 .
    } UNION {
      _:nrg_1071a property:product p:5550.
      _:nrg_1071a sdmx-measure:obsValue ?nrg_1071a_5550 .
    } UNION {
      _:nrg_1071a property:product p:5540.
      _:nrg_1071a sdmx-measure:obsValue ?nrg_1071a_5540 .
    }  
  }  
 }
}
GROUP BY ?date
ORDER BY ?date