Contribution of renewable energy sources to gross inland energy consumption

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>
PREFIX indic_nrg: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_nrg/>

SELECT 
year(?date) as ?year

(round((sum(?nrg_107a_5532)/sum(?nrg_100a))*1000))/10.0 as ?solar_thermal
(round((sum(?nrg_107a_5534)/sum(?nrg_100a))*1000))/10.0 as ?solar_photovoltaic
(round((sum(?nrg_107a_5520)/sum(?nrg_100a))*1000))/10.0 as ?wind
(round((sum(?nrg_107a_5550)/sum(?nrg_100a))*1000))/10.0 as ?geothermal
(round((sum(?nrg_107a_5510)/sum(?nrg_100a))*1000))/10.0 as ?hydro
(round((sum(?nrg_107a_biomass_and_waste)/sum(?nrg_100a))*1000))/10.0 as ?biomass_and_waste
(round((sum(?nrg_107a_liquid_biomass)/sum(?nrg_100a))*1000))/10.0 as ?liquid_biomass

WHERE {
{  
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_100a.rdf.gz> 
  {
  _:nrg_100a sdmx-dimension:refArea geo:EU28 .
  _:nrg_100a sdmx-attribute:unitMeasure unit:1000TOE .
  _:nrg_100a property:product product:0000 .
  _:nrg_100a sdmx-dimension:timePeriod ?date .
  _:nrg_100a property:indic_nrg indic_nrg:B_100900 .
  _:nrg_100a sdmx-measure:obsValue ?nrg_100a .
  }

  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_107a.rdf.gz> 
  {
  _:nrg_107a sdmx-dimension:refArea geo:EU28 .
  _:nrg_107a sdmx-attribute:unitMeasure unit:1000TOE .
  _:nrg_107a sdmx-dimension:timePeriod ?date .
  _:nrg_107a property:indic_nrg indic_nrg:B_100900 .
    { 
      _:nrg_107a property:product product:5510 .
      _:nrg_107a sdmx-measure:obsValue ?nrg_107a_5510 .
    } UNION {
      _:nrg_107a property:product product:5520 .
      _:nrg_107a sdmx-measure:obsValue ?nrg_107a_5520 .
    } UNION { 
      _:nrg_107a property:product product:5532 .
      _:nrg_107a sdmx-measure:obsValue ?nrg_107a_5532 .
    } UNION { 
      _:nrg_107a property:product product:5534 .
      _:nrg_107a sdmx-measure:obsValue ?nrg_107a_5534 .
    } UNION {
      _:nrg_107a property:product product:5550 .
      _:nrg_107a sdmx-measure:obsValue ?nrg_107a_5550 .
    } UNION {
      _:nrg_107a property:product ?product .
      FILTER (?product in (product:5541,product:5542,product:55431))
      _:nrg_107a sdmx-measure:obsValue ?nrg_107a_biomass_and_waste .
    } UNION {
      _:nrg_107a property:product ?product .
      FILTER (?product in (product:5546,product:5547,product:5548,product:5549))
      _:nrg_107a sdmx-measure:obsValue ?nrg_107a_liquid_biomass .
     }  
  }
 }
}
GROUP BY ?date