Average annual growth rates for different fuels 2005-2016

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>
PREFIX indic_nrg: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_nrg/>

SELECT 
?product_label
'2005-2016' as ?period
round(((bif:power((sum(?last_year)/sum(?first_year)),(1/11.0)))-1)*10000)/100.0 as ?value

{{
SELECT
?product_label
bif:either (year(?date) = 2005, sum(?B_100900) - COALESCE(sum(?B_101600),0), 0) as ?first_year 
bif:either (year(?date) = 2016, sum(?B_100900) - COALESCE(sum(?B_101600),0), 0) as ?last_year

WHERE {
  {  
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_100a.rdf.gz> 
    {
    _:nrg_100a sdmx-dimension:refArea geo:EU28 .
    _:nrg_100a sdmx-attribute:unitMeasure unit:KTOE .
    _:nrg_100a sdmx-dimension:timePeriod ?date .
    
    _:nrg_100a property:product ?product . 
    FILTER (?product in (product:2000, product:3000, product:4000, product:5100, product:5500))
    {
      _:nrg_100a property:indic_nrg indic_nrg:B_100900 .
      _:nrg_100a sdmx-measure:obsValue ?B_100900 .
    } UNION {
      _:nrg_100a property:indic_nrg indic_nrg:B_101600 .
      _:nrg_100a sdmx-measure:obsValue ?B_101600 .
    }

    } 
    ?product rdfs:label ?product_label .
  }
}

GROUP BY ?date ?product_label ?product

}}
ORDER BY  ?product_label