Growth in transport energy consumption, 1990-2016

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>
PREFIX indic_nrg: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_nrg/>
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX estat_countries: <http://rdfdata.eionet.europa.eu/eea/countries/>

SELECT
'' as ?dummy
bif:either(?memberOf_label = 'NMS13', 'EU-13', 
bif:either(?memberOf_label = 'EU15', 'EU-15', 
bif:either(?memberOf_label = 'EEA33', 'EEA-33', 
?memberOf_label))) as ?memberOf_label
round((( SUM(?last_year)-SUM(?first_year) ) / SUM(?first_year) )*1000)/10.0 as ?index
{{
  SELECT DISTINCT
  ?date
  ?memberOf_label
  bif:either(year(?date) = 1990, (sum(?0000)-sum(?2000)), 0) as ?first_year
  bif:either(year(?date) = 2016, (sum(?0000)-sum(?2000)), 0) as ?last_year

  WHERE {
  {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_100a.rdf.gz>
      {
        _:nrg_100a sdmx-dimension:timePeriod ?date . 
        FILTER (year(?date) in (1990, 2016))
        _:nrg_100a sdmx-attribute:unitMeasure unit:TJ . 
        _:nrg_100a property:indic_nrg ?indic_nrg .
        FILTER (?indic_nrg in (indic_nrg:B_100800, indic_nrg:B_101910, 
                               indic_nrg:B_101920, indic_nrg:B_101940, 
                               indic_nrg:B_101931, indic_nrg:B_101932))
        _:nrg_100a sdmx-dimension:refArea ?geo .
        {
          _:nrg_100a property:product product:0000 .
          _:nrg_100a sdmx-measure:obsValue ?0000 .
        } UNION {
          _:nrg_100a property:product product:2000 .
          _:nrg_100a sdmx-measure:obsValue ?2000 .
        }
      }
    } 
    ?geo skos:notation ?ugeo .
    ?eeageo owl:sameAs ?geo .
    ?eeageo skos:inScheme estat_countries: .
    ?memberOf skos:member ?eeageo .
    FILTER (?memberOf IN (estat_countries:EEA33, estat_countries:NMS13, estat_countries:EU15)) .
    ?memberOf skos:notation ?memberOf_label
  }
GROUP BY ?memberOf ?memberOf_label ?date

}}
GROUP BY ?memberOf_label
ORDER BY ?memberOf_label